Schneeflockenkurve - Listing

Dokumentation ansehen
Programmspeicher-Image laden

10	"K" CLEAR :CLS :WAIT 0:DEGREE :CLOSE
20	PRINT "Kochsche Schneeflocke":M$="B"
30	PRINT "B (erechnen)":PRINT "Z (eichnen)":INPUT M$
40	CLS :IF M$="B" GOTO 70
50	IF M$="Z" GOTO 240
60	GOTO 20
70	WAIT :PRINT "CE-140F o.k.? <ENTER>":WAIT 0:CLS
80	PRINT "Maximale Ordnung :":INPUT "n = ";N
90	CLS :IF N<2 BEEP 2:GOTO 80
100	PRINT "":PRINT " *** BUSY ***":CURSOR 0,3:PRINT 1;
110	OPEN "X:KOCH.1" FOR OUTPUT AS #3:PRINT #3,0,0:CLOSE
120	R=2:FOR I=2 TO N:R=R/3:PRINT I;
130	F$="KOCH."+STR$ I:G$="KOCH."+STR$ (I-1)
140	OPEN "X:"+G$ FOR INPUT AS #2:OPEN "X:"+F$ FOR OUTPUT AS #3
150	FOR J=1 TO 6^(I-2)
160	INPUT #2,U,V
170	FOR K=0 TO 5
180	X=U+R*COS (K*60):Y=V+R*SIN (K*60)
190	PRINT #3,X,Y
200	NEXT K
210	NEXT J
220	CLOSE :NEXT I
230	CLS :BEEP 2:M$="Z":GOTO 30
240	PRINT "CE-140F o.k.?":WAIT :PRINT "CE-140P o.k.? <ENTER>":WAIT 0:CLEAR
250	CLS :PRINT "Ordnung:":PRINT "Radius : mm":PRINT "Farbe :"
260	R=48:N=3:CURSOR 9,0:INPUT N:CURSOR 9,1:INPUT R:CURSOR 9,2:INPUT C
270	IF R>48 OR R<10 OR N<1 GOTO 250
280	CLS :S=R*5:T=S:A=[FC]3*R:P=4*A
290	LTEXT :LPRINT CHR$ 27+"@
300	LPRINT "Kochsche Schneeflocke ";N;"Ordnung
310	GRAPH :GLCURSOR (240,-S):SORGN :COLOR C,7
320	CIRCLE (0,0),T,C,0,360,1,120:CIRCLE (0,0),T,C,60,420,1,120
330	IF N=1 GOTO 440
340	FOR I=2 TO N:P=P+P/3:T=T/3
350	F$="KOCH."+STR$ I
360	OPEN "X:"+F$ FOR INPUT AS #2
370	FOR J=1 TO 6^(I-1)
380	INPUT #2,X,Y
390	X=X*S:Y=Y*S
400	B=60*(J/2<>INT (J/2)):E=360+B
410	CIRCLE (X,Y),T,C,B,E,1,120
420	NEXT J
430	CLOSE :NEXT I
440	GLCURSOR (-240,-S):SORGN :LTEXT :LF 2:COLOR 0,7
450	LPRINT "Kantenlaenge des Grunddreiecks :":LPRINT INT (A*10+.5)/10;" mm"
460	LPRINT "Umfang der Schneeflocke :":LPRINT INT (P*10+.5)/10;" mm"
470	LF 6
480	END

Dokumentation ansehen
Programmspeicher-Image laden