Sharp PC1360 |
Dokumentation ansehen
Programmspeicher-Image laden
| 10 | "J" CLS :CLEAR :WAIT 0 |
| 20 | INPUT "Anzahl Wertepaare: ";N:N=N-1 |
| 30 | DIM X(N),Y(N),B(N) |
| 40 | CLS :INPUT "X0 = ";U |
| 50 | INPUT "Y0 = ";Y(0) |
| 60 | V=U:X(0)=U |
| 70 | FOR I=1 TO N |
| 80 | CLS :PRINT "X";STR$ I;" =":CURSOR 7,0:INPUT X(I) |
| 90 | IF X(I)<U LET U=X(I) |
| 100 | IF X(I)>V LET V=X(I) |
| 110 | CURSOR 0,1:PRINT "Y";STR$ I;" =":CURSOR 7,1:INPUT Y(I) |
| 120 | NEXT I |
| 130 | CLS :PRINT "G (rafik)":PRINT "E (inzelwerte)":PRINT "W (ertetabelle) |
| 140 | INPUT "P (rogrammende) ";H$ |
| 150 | IF H$="G" GOSUB 410 |
| 160 | IF H$="E" GOSUB 220 |
| 170 | IF H$="W" GOSUB 840 |
| 180 | IF H$="P" GOTO 200 |
| 190 | GOTO 130 |
| 200 | CLS :END |
| 210 | REM Einzelwerte |
| 220 | CLS |
| 230 | INPUT "X = ";X |
| 240 | GOSUB 300 |
| 250 | PRINT =LPRINT |
| 260 | CLS :PRINT "X = ";X:WAIT :PRINT "Y = ";Y |
| 270 | PRINT =PRINT :WAIT 0 |
| 280 | RETURN |
| 290 | REM Wert berechnen |
| 300 | Y=0 |
| 310 | FOR K=O TO N |
| 320 | B(K)=1 |
| 330 | FOR J=0 TO N |
| 340 | IF J=K THEN 360 |
| 350 | B(K)=B(K)*(X-X(J))/(X(K)-X(J)) |
| 360 | NEXT J |
| 370 | Y=Y+B(K)*Y(K) |
| 380 | NEXT K |
| 390 | RETURN |
| 400 | REM Grafik |
| 410 | CLS :WAIT :PRINT "CE-140P o.k. ? <ENTER>":WAIT 0 |
| 420 | LPRINT CHR$ 27+"@ |
| 430 | CLS :INPUT "Anfangswert: ";A,"Endwert : ";B |
| 440 | IF B<=A BEEP 1:GOTO 430 |
| 450 | LPRINT " Lagrangepolynom -->":LF 3:GRAPH |
| 460 | GLCURSOR (10,0):CROTATE 1:LPRINT "PArgument -->":GLCURSOR (60,0):SORGN |
| 470 | LLINE (0,0)-(400,0)-(400,-500)-(0,-500)-(0,0 |
| 480 | CLS :PRINT "":PRINT " *** BUSY ***" |
| 490 | ERASE W:DIM W(50) |
| 500 | X=A:S=(B-A)/50 |
| 510 | GOSUB 300 :C=Y:D=Y:W(0)=Y |
| 520 | FOR I=1 TO 50 |
| 530 | X=X+S |
| 540 | GOSUB 300 :W(I)=Y |
| 550 | IF Y<C LET C=Y |
| 560 | IF Y>D LET D=Y |
| 570 | NEXT I |
| 580 | T=400/(D-C) |
| 590 | IF SGN C<>SGN D LLINE (-C*T,0)-(-C*T,500) |
| 600 | IF SGN A<>SGN B LLINE (0,A/S*10)-(400,A/S*10) |
| 610 | CSIZE 1:USING "##.##^" |
| 620 | FOR I=0 TO 50 STEP 10 |
| 630 | LLINE (0,-I*10)-(9,-I*10):GLCURSOR (-15,-I*10+25):LPRINT "P";MDF (A+I*S) |
| 640 | NEXT I |
| 650 | FOR I=0 TO 400 STEP 80 |
| 660 | LLINE (I,0)-(I,-9):GLCURSOR (I-4,65):LPRINT "P";MDF (C+I/T) |
| 670 | NEXT I |
| 680 | GLCURSOR ((W(0)-C)*T,0) |
| 690 | X=A:COLOR 2,7 |
| 700 | FOR I=1 TO 50 |
| 710 | ON Q GOTO 730 ,740 |
| 720 | IF X>=U COLOR 4,7:Q=1 |
| 730 | IF X>V COLOR 2,7:Q=2 |
| 740 | LLINE -((W(I)-C)*T,-I*10) |
| 750 | X=X+S |
| 760 | NEXT I |
| 770 | FOR I=N TO 0 STEP -1 |
| 780 | CIRCLE ((Y(I)-C)*T,(A-X(I))/S*10),4,5,45,405,1,90 |
| 790 | NEXT I |
| 800 | LPRINT CHR$ 27+"@":LF 25 |
| 810 | CLS :USING |
| 820 | RETURN |
| 830 | REM Wertetabelle |
| 840 | CLS :INPUT "Anfangswert : ";A,"Endwert : ";B,"Schrittweite: ";S |
| 850 | PRINT =LPRINT |
| 860 | CLS :PRINT " X ";CHR$ 124;" Y":PRINT "----------------------- |
| 870 | USING "##.###^":I=1 |
| 880 | FOR X=A TO B STEP S |
| 890 | GOSUB 300 |
| 900 | PRINT MDF X;" ";CHR$ 124;" ";MDF Y |
| 910 | IF I/4=INT (I/4) WAIT :PRINT :WAIT 0 |
| 920 | I=I+1 |
| 930 | NEXT X |
| 940 | WAIT :PRINT :WAIT 0 |
| 950 | PRINT =PRINT :USING |
| 960 | RETURN |
Dokumentation ansehen
Programmspeicher-Image laden
|
|
Falls diese Seite ohne Navigationsleiste angezeigt wird, aktivieren Sie Javascript oder klicken Sie hier!