Matrizenprodukt - Listing

Dokumentation ansehen
Programmspeicher-Image laden

10	"M" CLEAR :WAIT 0:CLS
20	PRINT "Matrizenprodukt :":X$=CHR$ 91+"X"+CHR$ 93+"="
30	A$=CHR$ 91+"A"+CHR$ 93+"*"+CHR$ 91+"B"+CHR$ 93
40	PRINT X$;A$:PRINT ""
50	PRINT "A(I,J)":CURSOR 12,3:INPUT "I = ";I,"J = ";J:CURSOR 0,3
60	PRINT "B(J,K)":CURSOR 12,3:INPUT "K = ";K
70	I=I-1:J=J-1:K=K-1
80	DIM A(I,J),B(J,K),X(I,K)
90	FOR L=0 TO I:FOR M=0 TO J
100	CURSOR 12,3:PRINT " ":CURSOR 0,3
110	PRINT "A(";STR$ (L+1);",";STR$ (M+1);") =":CURSOR 13,3
120	INPUT A(L,M):CURSOR 0,3
130	NEXT M:NEXT L
140	CURSOR 12,3:PRINT " ":CURSOR 0,3
150	FOR L=0 TO J:FOR M=0 TO K
160	CURSOR 12,3:PRINT " ":CURSOR 0,3
170	PRINT "B(";STR$ (L+1);",";STR$ (M+1);") =":CURSOR 13,3
180	INPUT B(L,M):CURSOR 0,3
190	NEXT M:NEXT L
200	CLS :PRINT "":PRINT " *** BUSY ***"
210	FOR L=0 TO I:FOR M=0 TO K:FOR N=0 TO J
220	X(L,M)=X(L,M)+A(L,N)*B(N,M)
230	NEXT N:NEXT M:NEXT L
240	CLS :BEEP 1
250	WAIT :FOR L=0 TO I:FOR M=0 TO K
260	PRINT "X(";STR$ (L+1);",";STR$ (M+1);") = ";STR$ X(L,M)
270	NEXT M:NEXT L
280	END

Dokumentation ansehen
Programmspeicher-Image laden