Funktionenplotter - Listing

Dokumentation ansehen
Programmspeicher-Image laden
Javascript-Programm

10	"G" CLEAR :LTEXT :WAIT 0:LPRINT CHR$ 27+"@"
20	COLOR 0,7:USING :CLS
30	PRINT "Funktion in Zeile 580":PRINT "in der Form y=f(x)":WAIT :PRINT "eingegeben ?":WAIT 0
40	CLS :INPUT "Anfangswert : ";A,"Endwert : ";B,"Schrittweite : ";C
50	CLS :INPUT "Farbe (0-6) : ";F,"Vorschub (cm) : ";V:V=V/.02
60	N=(B-A)/C
70	DIM U$(1)*25,F(N)
80	CLS :PRINT "Achsenbeschriftung :":INPUT "X-Achse : ";U$(1),"Y-Achse : ";U$(0)
90	CLS :PRINT "":PRINT " *** BUSY ***"
100	X=A:GOSUB "FKT2"
110	S=Y:T=Y:F(0)=Y
120	FOR X=A+C TO B STEP C
130	GOSUB "FKT2"
140	IF Y<S LET S=Y
150	IF Y>T LET T=Y
160	I=I+1:F(I)=Y
170	NEXT X
180	BEEP 1:CLS
190	PRINT "X min = ";A:PRINT "X max = ";B:INPUT "X-Skalenteil : ";DX,"Format : ";L$
200	CLS
210	PRINT "Y min = ";S:PRINT "Y max = ";T:INPUT "Y-Skalenteil : ";DY,"Format : ";M$
220	CLS :PRINT "":PRINT " *** BUSY ***"
230	LPRINT " "+U$(0)+" -->"
240	GRAPH
250	GLCURSOR (10,0):CROTATE 1
260	LPRINT "P"+U$(1)+" -->"
270	GLCURSOR (40,0):SORGN
280	LLINE (0,0)-(440,0)-(440,-V)-(0,-V)-(0,0)
290	MX=V/(B-A):MY=440/(T-S)
300	USING M$:CSIZE 1
310	DY=DY*MY
320	FOR I=DY TO 438 STEP DY
330	LLINE (I,0)-(I,-5)
340	LPRINT "P";MDF (I/MY+S)
350	NEXT I
360	IF SGN A=SGN B THEN 410
370	FOR I=DY TO 438 STEP DY
380	LLINE (I,A*MX+5)-(I,A*MX-5)
390	NEXT I
400	LLINE (440,A*MX)-(0,A*MX)
410	USING L$:DX=DX*MX
420	FOR I=DX TO V-DX+1 STEP DX
430	LLINE (0,-I)-(5,-I)
440	LPRINT "P";MDF (I/MX+A)
450	NEXT I
460	IF SGN T=SGN S THEN 510
470	FOR I=DX TO V-DX STEP DX
480	LLINE (-S*MY-5,-I)-(-S*MY+5,-I)
490	NEXT I
500	LLINE (-S*MY,-V)-(-S*MY,0)
510	GLCURSOR ((F(0)-S)*MY,0)
520	FOR I=1 TO N
530	LLINE -((F(I)-S)*MY,-I*V/N),0,F
540	NEXT I
550	CLS :LTEXT :LF 10
560	END
570	"FKT2"
580	Y=COS X - SIN X * COS(X+10)
590	RETURN

Dokumentation ansehen
Programmspeicher-Image laden
Javascript-Programm