Primzahlen - Listing

Javascript zur Primzahlberechnung und Primfaktorzerlegung
Dokumentation ansehen
Programmspeicher-Image laden

10	"Z" CLEAR :DIM N$(0)*12:CLS
20	WAIT 0:PRINT "N (eues File)":PRINT "A (ltes File)"
30	INPUT H$
40	INPUT "Filename : ";N$(0)
50	CLS :PRINT "Diskette eingelegt ?":WAIT :PRINT "<ENTER>"
60	IF LEFT$ (H$,1)="A" OPEN "X:"+N$(0) FOR APPEND AS #2
70	IF LEFT$ (H$,1)="N" OPEN "X:"+N$(0) FOR OUTPUT AS #2
80	INPUT "Anfangswert : ";U,"Endwert : ";O
90	IF U/2=INT (U/2) LET U=U-1
100	IF U<10 PRINT #2,2;3;5;7:U=11
110	WAIT 0
120	CLS :PRINT "":PRINT " *** BUSY ***"
130	I=3
140	IF U>O THEN 190
150	Q=U/I
160	IF Q=INT Q LET U=U+2:GOTO 130
170	IF I>=SQR U PRINT #2,U;:U=U+2:GOTO 130
180	I=I+2:GOTO 150
190	CLS :CLOSE
200	WAIT
210	END
220	"X" CLEAR :DIM N$(0)*12:CLS :INPUT "Obergrenze: ";O
230	INPUT "Filename : ";N$(0)
240	WAIT 0
250	PRINT "Diskette eingelegt ?":WAIT :PRINT "<ENTER>"
260	OPEN "X:"+N$(0) FOR INPUT AS #3
270	WAIT 0
280	IF EOF 3 PRINT "":PRINT "Bitte Diskette wechseln!":CLOSE :GOTO 230
290	INPUT #3,P
300	IF P>O THEN 380
310	PRINT P;
320	IF INKEY$ <>"" THEN 320
330	J=J+1
340	IF J>1 LET D=P-Z
350	Z=P
360	M=M+D:N=N+D*D
370	GOTO 280
380	CLOSE
390	M=M/(J-1):S=SQR (N/(J-1)-M*M)
400	PRINT
410	USING "##.###^"
420	PRINT "Abstand der Primzahlen":PRINT "zwischen ";STR$ U:PRINT "und ";STR$ O:WAIT
430	PRINT "Mittelwert :";M:PRINT "Standardabw.:";S
440	USING :PRINT "Anzahl : ";J
450	END
460	"C" WAIT 0:CLS
470	PRINT "Zu testende Zahl :":INPUT "X = ";X
480	IF X<>INT X OR X<=0 OR X>=1E10 CLS :PRINT "Eingabefehler !":GOTO 470
490	IF X=1 PRINT "Gemaess Definition ist 1keine Primzahl !":END
500	IF X=2 THEN 550
510	FOR I=2 TO SQR X
520	Q=X/I
530	IF Q=INT Q THEN 560
540	NEXT I
550	BEEP 2:PRINT "Die Zahl ";STR$ X:PRINT "ist eine Primzahl !":GOTO 580
560	BEEP 1:PRINT "Die Zahl ";STR$ X:PRINT "ist keine Primzahl, ihr kleinster Teiler ist"
570	WAIT :PRINT I:X=X/I:WAIT 0:GOTO 480
580	WAIT
590	END

Javascript zur Primzahlberechnung und Primfaktorzerlegung
Dokumentation ansehen
Programmspeicher-Image laden