Sharp PC1360 Taschencomputer
 

 Sharp PC1360

Das Einsiedlerspiel - Listing

Javascriptprogramm
Dokumentation ansehen/laden
Programmspeicher-Image laden

10"S" CLS :CLEAR :WAIT 0:RESTORE 230 :DIM Z(6,6),R$(1,30)*2:GCURSOR (45,7)
20Z(0,0)=2:Z(0,1)=2:Z(1,0)=2:Z(1,1)=2:Z(0,5)=2:Z(0,6)=2:Z(1,5)=2:Z(1,6)=2
30Z(5,0)=2:Z(5,1)=2:Z(6,0)=2:Z(6,1)=2:Z(5,5)=2:Z(5,6)=2:Z(6,5)=2:Z(6,6)=2
40GPRINT "CEDFDBDBDBDBFB73007EFFC3C3C3C3FF7E00FFFFC0C0C0C0C0C000FFFF00030303FFFF";
50GPRINT "03030300FEFF33333333FFFE00FFFF00FFFF1B1B3B7BDF8E00FFFFDBDBDBC3C3C3
60FOR I=0 TO 4 STEP 4: LINE (1+I,9)-(29-I,21),B: LINE (21,I+1)-(9,29-I),B
70LINE (1,9+I)-(29,21-I),B: LINE (21-I,1)-(9+I,29),B: NEXT I
80FOR I=0 TO 31:READ A,B: Z(A,B)=1: PSET (A*4+3,B*4+3): NEXT I
90CURSOR 9,2:PRINT "von :": CURSOR 9,3: PRINT "nach:"
100CURSOR 14,2: PRINT " ": CURSOR 14,3: PRINT " "
110CURSOR 15,2: INPUT R$(0,K):IF R$(0,K)="E" GOTO 250
120CURSOR 15,3: INPUT R$(1,K):IF R$(1,K)="E" GOTO 250
130A=VAL LEFT$ (R$(0,K),1)-1: B=VAL RIGHT$ (R$(0,K),1)-1
140C=VAL LEFT$ (R$(1,K),1)-1: D=VAL RIGHT$ (R$(1,K),1)-1
150H=ABS (A-C): G=ABS (B-D)
160IF A<0 OR B<0 OR C<0 OR D<0 BEEP 1: GOTO 100
170IF H=G OR (H<>0 AND H<>2) OR (G<>0 AND G<>2) OR Z(A,B)=0 OR Z(C,D)=1 BEEP 1: GOTO 100
180IF Z(A,B)=2 OR Z(C,D)=2 BEEP 1: GOTO 100
190PRESET (B*4+3,A*4+3): Z(A,B)=0: PSET (D*4+3,C*4+3): Z(C,D)=1
200U=A+(C-A)/2: V=B+(D-B)/2: PRESET (V*4+3,U*4+3): Z(U,V)=0
210K=K+1: IF K=31 GOTO 250
220GOTO 100
230DATA 0,2,0,3,0,4,1,2,1,3,1,4,2,0,2,1,2,2,2,3,2,4,2,5,2,6,3,0,3,1,3,2,3,4,3,5,3
240DATA 6,4,0,4,1,4,2,4,3,4,4,4,5,4,6,5,2,5,3,5,4,6,2,6,3,6,4
250BEEP 3: CLS : IF K=31 CURSOR 9,2: PAUSE "Gewonnen !"
260WAIT : CURSOR 9,3:PRINT "Drucker o.k.?
270CONSOLE 32: FOR I=0 TO K-1: LPRINT R$(0,I);"-";R$(1,I);
280IF I<>K LPRINT " / ";
290NEXT I
300CONSOLE 39: CLS
310END

Javascriptprogramm
Dokumentation ansehen/laden
Programmspeicher-Image laden


Zur Übersichtstabelle



Home
Falls diese Seite ohne Navigationsleiste angezeigt wird, aktivieren Sie Javascript oder klicken Sie hier!