Sharp PC1360 |
Dokumentation ansehen
Programmspeicher-Image laden
Javascript-Programm
| 10 | "V" RANDOM :CLS :WAIT 0:M$="L":CLEAR C,D |
| 20 | PRINT "L(ernen)":PRINT "E(ingeben)":INPUT M$ |
| 30 | IF M$="L" GOTO 60 |
| 40 | IF M$="E" GOTO 290 |
| 50 | GOTO 10 |
| 60 | IF F=1 CLS :M$="N":PRINT "geladene Lektion :":PRINT L$:INPUT "neu laden <N/J> ? ";M$ |
| 70 | IF M$="J" LET F=0 |
| 80 | IF F GOTO 150 |
| 90 | CLEAR :CLS :WAIT :PRINT "CE-140F o.k.?":WAIT 0 |
| 100 | CLS :L$="1":INPUT "Lektion-Nr.: ";L$ |
| 110 | L$="UNITA"+L$:CLS |
| 120 | PRINT " *** BUSY ***" |
| 130 | OPEN "X:"+L$+".ITL" FOR INPUT AS #2:INPUT #2,V:DIM V$(1,V-1)*23 |
| 140 | INPUT #2,V$(*):CLOSE :F=1 |
| 150 | ERASE X$:DIM X$(0)*23 |
| 160 | CLS :A=1:PRINT "1 = deutsch/italienisch":PRINT "2 = italienisch/deutsch" |
| 170 | PRINT "3 = abwechselnd":INPUT A |
| 180 | T=A-1:S=NOT T+2 |
| 190 | IF A=3 LET S=1:T=0 |
| 200 | IF A=3 LET S=T:T=NOT T+2 |
| 210 | X$(0)="":R=RND V-1 |
| 220 | CLS :PRINT V$(S,R):INPUT X$(0) |
| 230 | IF X$(0)="" GOTO 270 |
| 240 | D=D+1:IF X$(0)=V$(T,R) BEEP 1,8,200:GOTO 200 |
| 250 | C=C+1:BEEP 1,255,150:CURSOR 0,1:PRINT " ":CURSOR 0,1 |
| 260 | WAIT :PRINT V$(T,R):WAIT 0:GOTO 200 |
| 270 | CLS :E$=STR$ INT (C*100/D+.5):PRINT "Fehlerrate: ";E$;" %":PRINT "von ";STR$ D;" Vokabeln" |
| 280 | POKE 12348,16:END |
| 290 | CLS :M$="N":PRINT "N(eueingabe)":PRINT "B(erichtigung)":PRINT "A(bspeichern)":INPUT M$ |
| 300 | IF M$="N" GOTO 340 |
| 310 | IF M$="B" GOTO 440 |
| 320 | IF M$="A" GOTO 490 |
| 330 | GOTO 290 |
| 340 | CLEAR :CLS :INPUT "Lektion-Nr.: ";L$:L$="UNITA"+L$ |
| 350 | CLS :PRINT "Anzahl Vokabelpaare :":INPUT V |
| 360 | IF V<10 OR V>255 BEEP 1,39:GOTO 350 |
| 370 | DIM V$(1,V-1)*23 |
| 380 | CLS :PRINT "italienisch :":CURSOR 0,2:PRINT "deutsch :" |
| 390 | FOR I=0 TO V-1 |
| 400 | CURSOR 0,1:PRINT " ":CURSOR 0,3:PRINT " " |
| 410 | CURSOR 0,1:INPUT V$(0,I) |
| 420 | CURSOR 0,3:INPUT V$(1,I) |
| 430 | NEXT I:F=1 |
| 440 | FOR I=0 TO V-1:CLS |
| 450 | PRINT V$(0,I):CURSOR 0,2:PRINT V$(1,I) |
| 460 | CURSOR 0,1:INPUT V$(0,I) |
| 470 | CURSOR 0,3:INPUT V$(1,I) |
| 480 | NEXT I |
| 490 | CLS :WAIT :PRINT "CE-140F o.k.?":WAIT 0 |
| 500 | CLS :PRINT " *** BUSY ***" |
| 510 | OPEN "X:"+L$+".ITL" FOR OUTPUT AS #2 |
| 520 | PRINT #2,V;V$(*) |
| 530 | CLOSE :POKE 12348,16 |
| 540 | CLS :END |
Dokumentation ansehen
Programmspeicher-Image laden
Javascript-Programm
|
|
Falls diese Seite ohne Navigationsleiste angezeigt wird, aktivieren Sie Javascript oder klicken Sie hier!